外付けハードディスクへ簡単バックアップ (Remix.asia)

　実家でデジカメを頻繁に使うようになり、保存・編集・印刷・メール送信などパソコンが活用されはじめてきたので、万が一に備え簡単にバックアップできる仕組みを準備。
前提環境
●Windows XP Pro / Home SP3
●XP標準の「バックアップユーティリティ」(XP Home ではデフォルトでインストールされないのでこちらを参考)
●ＵＳＢ・IEEE1394接続外付けハードディスク

動作要件
●外付けハードディスクを任意のタイミングで接続すると自動的にバックアップを実施。
●バックアップ対象はあらかじめ「バックアップユーティリティ」でバックアップセットとして設定保存。
●初回(バックアップファイルがない状態)は、新規に完全バックアップ。
●次回以降(バックアップファイルがある状態)は、追加で増分バックアップ。
●バックアップファイル名は、Backup_コンピューター名_ログインユーザー名.bkf として、コンピューターとログインユーザーで区別。
手順↓

【準備編】
★あらかじめバックアップ対象をフォルダ単位で選択・登録。
[スタート]→[すべてのプログラム]→[アクセサリ]→[システムツール]→[バックアップ]
か
[スタート]→[ファイル名を指定して実行] で ntbackup を起動。

※ ログインしているユーザーにバックアップ対象を読み出せる権限が必要。ほとんどのパーソナルユースでは管理者権限。

★「詳細モードに切り替えて実行する」をクリック。

★バックアップしたいフォルダをチェック。

★ジョブ→選択したジョブの保存。

★ファイル名を必ず『MySet.bks』で保存。
「バックアップユーティリティ」を終了。

※ ユーザー別にバックアップする場合、各ユーザーで上記実施。他のパソコンも同様。

★外付けハードディスクのルート(最上位)に次の２ファイルを配置(フォルダはＮＧ)。
Autorun.inf

[Autorun]
open=MyBackup.cmd

MyBackup.cmd

echo off
echo.
SET /P=接続メディアの %~d0\Backup_%COMPUTERNAME%_%USERNAME%.bkf へ<nul
IF EXIST Backup_%COMPUTERNAME%_%USERNAME%.bkf (
echo 追加増分バックアップしています。
) ELSE (
echo 新規通常バックアップしています。
)
echo.
echo バックアップが終了するまでしばらくお待ちください。
IF EXIST Backup_%COMPUTERNAME%_%USERNAME%.bkf (
ntbackup.exe backup "@%USERPROFILE%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\MySet.bks" /a /l:f /v:no /r:no /rs:no /hc:off /d "追加増分" /f "%~d0\Backup_%COMPUTERNAME%_%USERNAME%.bkf" /m incremental
) ELSE (
ntbackup.exe backup "@%USERPROFILE%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\MySet.bks" /a /l:f /v:no /r:no /rs:no /hc:off /d "新規完全" /f "%~d0\Backup_%COMPUTERNAME%_%USERNAME%.bkf" /m normal
)
echo.
echo バックアップが終了しました。
echo.
dir %~d0\Backup_%COMPUTERNAME%_%USERNAME%.bkf
echo.
echo 接続メディアの残容量が少なくなったら %~d0\Backup_%COMPUTERNAME%_%USERNAME%.bkf を他の場所へ移動してください。
echo.
for /F %%F in ('dir /b /o:D /a:-d "%USERPROFILE%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\*.log"') do set LOGNAME=%%F
echo バックアップレポートは
echo.
echo %USERPROFILE%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\%LOGNAME%
echo.
echo です。
echo.
echo レポートを参照する場合だけ [e] を入力し、エンターで終了します。
set /p INPUT=
if defined INPUT set INPUT=%INPUT:"=%
if /i "%INPUT%" == "e" "%USERPROFILE%\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\%LOGNAME%"

準備完了。ベクターで入手可能。